Another Modbus slave example

I've also tried to work on a easy to understand example, which could cover most of the Arduino I/O:

The comments in the code are quite explicit regarding to the I/O mapping. The code looks like this:

/**
 *  Modbus object declaration
 *  u8id : node id = 0 for master, = 1..247 for slave
 *  u8serno : serial port (use 0 for Serial)
 *  u8txenpin : 0 for RS-232 and USB-FTDI
 *               or any pin number > 1 for RS-485
 *
 * pin maping:
 * 2 - digital input
 * 3 - digital input
 * 4 - digital input
 * 5 - digital input
 * 6 - digital output
 * 7 - digital output
 * 8 - digital output
 * 9 - digital output
 * 10 - analog output
 * 11 - analog output
 * 14 - analog input
 * 15 - analog input
 */
#define ID   3

Modbus slave(ID, 0, 0);
boolean led;
int8_t state = 0;
unsigned long tempus;
// data array for modbus network sharing
uint16_t au16data[9];


void setup() {
  // define i/o
  pinMode(2, INPUT);
  pinMode(3, INPUT);
  pinMode(4, INPUT);
  pinMode(5, INPUT);
  pinMode(6, OUTPUT);
  pinMode(7, OUTPUT);
  pinMode(8, OUTPUT);
  pinMode(9, OUTPUT);
  pinMode(10, OUTPUT);
  pinMode(11, OUTPUT);
  pinMode(13, OUTPUT);

  digitalWrite(6, LOW );
  digitalWrite(7, LOW );
  digitalWrite(8, LOW );
  digitalWrite(9, LOW );
  digitalWrite(13, HIGH );
  analogWrite(10, 0 );
  analogWrite(11, 0 );

  // start communication
  slave.begin( 19200 );
  tempus = millis() + 100;
  digitalWrite(13, HIGH );
}


void loop() {
  // poll messages
  // blink led pin on each valid message
  state = slave.poll( au16data, 9 );
  if (state > 4) {
    tempus = millis() + 50;
    digitalWrite(13, HIGH);
  }
  if (millis() > tempus) digitalWrite(13, LOW );

  // get digital inputs -> au16data[0]
  bitWrite( au16data[0], 0, digitalRead( 2 ));
  bitWrite( au16data[0], 1, digitalRead( 3 ));
  bitWrite( au16data[0], 2, digitalRead( 4 ));
  bitWrite( au16data[0], 3, digitalRead( 5 ));

  // set digital outputs -> au16data[1]
  digitalWrite( 6, bitRead( au16data[1], 0 ));
  digitalWrite( 7, bitRead( au16data[1], 1 ));
  digitalWrite( 8, bitRead( au16data[1], 2 ));
  digitalWrite( 9, bitRead( au16data[1], 3 ));

  // set analog outputs
  analogWrite( 10, au16data[2] );
  analogWrite( 11, au16data[3] );

  // read analog inputs
  au16data[4] = analogRead( 0 );
  au16data[5] = analogRead( 1 );

  // diagnose communication
  au16data[6] = slave.getInCnt();
  au16data[7] = slave.getOutCnt();
  au16data[8] = slave.getErrCnt();
} 

The Arduino sketch is fully available here. The old link is still available, but this example is fully implemented in the "Advanced Slave" example, included in my last release of the Library.

As an sketch summary,

• pin 13 is used to show valid messages and it is lit for 50ms after getting a valid message;
• this same feature could be used to implement a communication watchdog, which could disable digital outputs when there are no incoming queries from the master;
• pins from 2 to 5 are digital inputs and are available in bits 0-3 of word au16data[0];
• something similar for pins from 6 to 9 and word au16data[1];
• the same pattern repeats for analog outputs and analog inputs;
• as an addition, here appear the diagnostics words of Modbus library.

I've checked the communication link with QModbus. QModbus settings are:

• Serial port: dev/ttyUSB1 (yes, I'm running a Linux Mint Box)
• Serial port settings: 19200 baud, 8N1
• Slave ID: 3 

Modbus function 3 allows to access to the whole memory map, while functions 15 and 16 should be reserved to write coils (digital outputs) and registers (analog outputs). Anyway there is no restriction to write words 0 or 4, but the loop() section will overwrite these values.